"AND" "OR"
Главная Информер Журнал Форум

Как сделать, чтобы MessageBox автоматически закрывался через определённое время

Некоторые программы используют для информирования пользователя окошки, которые автоматически закрываются через определённый период времени, такие как ошибки принтера и т.д. В Visual Basic это сделать довольно сложно, но возможно.

 

'Module Code
Private Declare Function KillTimer Lib "user32" (ByVal hWnd As Long, ByVal nIDEvent As Long) As Long
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare Function SetForegroundWindow Lib "user32" (ByVal hWnd As Long) As Long
'// Сообщение, которое будет информировать о закрытии окошка с сообщением
Public Const NV_CLOSEMSGBOX As Long = &H5000&
Public Sub TimerProc(ByVal hWnd As Long, ByVal uMsg As Long, ByVal idEvent As Long, ByVal dwTime As Long)
    KillTimer hWnd, idEvent
    Select Case idEvent
    Case NV_CLOSEMSGBOX
        Dim hMessageBox As Long
        '// находим окно messagebox по заголовку
        hMessageBox = FindWindow("#32770", "Self Closing Message Box")
        '// если нашли, то передаём ему фокус и посылаем enter, чтобы закрыть его
        If hMessageBox Then
            Call SetForegroundWindow(hMessageBox)
            SendKeys "{enter}"
        End If
    End Select
End Sub


'Form Code
Private Declare Function SetTimer Lib "user32" (ByVal hWnd As Long, ByVal nIDEvent As Long, ByVal uElapse As Long, ByVal lpTimerFunc As Long) As Long

Private Sub cmdShowMsg_Click()
    '// покажем messagebox, который закроется через 4 секунды
   
    '// устанавливаем таймер на 4 секунды (4000 микросекунд)
    SetTimer hWnd, NV_CLOSEMSGBOX, 4000, AddressOf TimerProc
   
    '// вызываем функцию messagebox
    If MsgBox("Watch this message box close itself after four seconds. The printer is out of paper. Retry or Cancel? (Example)", vbRetryCancel + vbDefaultButton1, "Self Closing Message Box") = vbRetry Then
        MsgBox "Retry!"
    Else
        MsgBox "Cancel"
    End If
 
End Sub